# Copyright (C) 2003-2025 Free Software Foundation, Inc.

# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with GCC; see the file COPYING3.  If not see
# <http://www.gnu.org/licenses/>.

#
# elna support library routines
#
load_lib prune.exp
load_lib gcc-defs.exp
load_lib timeout.exp
load_lib target-libpath.exp

#
# ELNA_UNDER_TEST is the compiler under test.
#


set gpp_compile_options ""


#
# elna_version -- extract and print the version number of the compiler
#

proc elna_version { } {
    global ELNA_UNDER_TEST
    
    elna_init

    # ignore any arguments after the command
    set compiler [lindex $ELNA_UNDER_TEST 0]
    
    # verify that the compiler exists
    if { [is_remote host] || [which $compiler] != 0 } then {
	set tmp [remote_exec host "$compiler -v"]
	set status [lindex $tmp 0]
	set output [lindex $tmp 1]
	regexp " version \[^\n\r\]*" $output version
	if { $status == 0 && [info exists version] } then {
	    if [is_remote host] {
		clone_output "$compiler $version\n"
	    } else {
		clone_output "[which $compiler] $version\n"
	    }
	} else {
	    clone_output "Couldn't determine version of [which $compiler]\n"
	}
    } else {
	# compiler does not exist (this should have already been detected)
	warning "$compiler does not exist"
    }
}

#
# elna_init -- called at the start of each subdir of tests
#

proc elna_init { args } {
    global subdir
    global gpp_initialized
    global base_dir
    global tmpdir
    global libdir
    global gluefile wrap_flags
    global objdir srcdir
    global ALWAYS_ELNAFLAGS
    global TOOL_EXECUTABLE TOOL_OPTIONS
    global ELNA_UNDER_TEST
    global TESTING_IN_BUILD_TREE
    global TEST_ALWAYS_FLAGS

    # We set LC_ALL and LANG to C so that we get the same error messages as expected.
    setenv LC_ALL C
    setenv LANG C

    if ![info exists ELNA_UNDER_TEST] then {
	if [info exists TOOL_EXECUTABLE] {
	    set ELNA_UNDER_TEST $TOOL_EXECUTABLE
	} else {
	    if { [is_remote host] || ! [info exists TESTING_IN_BUILD_TREE] } {
		set ELNA_UNDER_TEST [transform gelna]
	    } else {
		set ELNA_UNDER_TEST [findfile $base_dir/../../gelna "$base_dir/../../gelna -B$base_dir/../../" [findfile $base_dir/gelna "$base_dir/gelna -B$base_dir/" [transform gelna]]]
	    }
	}
    }

    if ![is_remote host] {
	if { [which $ELNA_UNDER_TEST] == 0 } then {
	    perror "ELNA_UNDER_TEST ($ELNA_UNDER_TEST) does not exist"
	    exit 1
	}
    }
    if ![info exists tmpdir] {
	set tmpdir "/tmp"
    }

    if [info exists gluefile] {
	unset gluefile
    }

    elna_maybe_build_wrapper "${tmpdir}/elna-testglue.o"

    set ALWAYS_ELNAFLAGS ""

    # TEST_ALWAYS_FLAGS are flags that should be passed to every
    # compilation.  They are passed first to allow individual
    # tests to override them.
    if [info exists TEST_ALWAYS_FLAGS] {
	lappend ALWAYS_ELNAFLAGS "additional_flags=$TEST_ALWAYS_FLAGS"
    }

    if [info exists TOOL_OPTIONS] {
	lappend ALWAYS_ELNAFLAGS "additional_flags=$TOOL_OPTIONS"
    }

    verbose -log "ALWAYS_ELNAFLAGS set to $ALWAYS_ELNAFLAGS"

    verbose "elna is initialized" 3
}

#
# elna_target_compile -- compile a source file
#

proc elna_target_compile { source dest type options } {
    global tmpdir
    global gluefile wrap_flags
    global ALWAYS_ELNAFLAGS
    global ELNA_UNDER_TEST

    if { [target_info needs_status_wrapper] != "" && [info exists gluefile] } {
	lappend options "libs=${gluefile}"
	lappend options "ldflags=${wrap_flags}"
    }

    lappend options "timeout=[timeout_value]"
    lappend options "compiler=$ELNA_UNDER_TEST"

    set options [concat "$ALWAYS_ELNAFLAGS" $options]
    set options [dg-additional-files-options $options $source $dest $type]
    return [target_compile $source $dest $type $options]
}